# Maintainer: Jonathan Apodaca <jrapodaca@gmail.com>
# Contributor: Sven-Hendrik Haase <svenstaro@gmail.com>
# Contributor: Florian Walch <florian+aur@fwalch.com>
# Contributor: Florian Hahn <flo@fhahn.com>

pkgname=neovim-bin
pkgver=0.9.5
pkgrel=2
pkgdesc='Fork of Vim aiming to improve user experience, plugins, and GUIs'
arch=('amd64')
url='https://neovim.io'
license=('custom:neovim')
provides=('neovim' 'neovim-runtime')
makedepends=('squashfs-tools')
depends=('libluajit-5.1-2' 'libluajit-5.1-common' 'libmsgpackc2' 'libtermkey1' 'libunibilium4' 'libvterm0' 'lua-luv')
conflicts=('neovim' 'neovim-git' 'neovim-runtime')
extensions=('zipman')
source=(
        "nvim-${pkgver}.appimage::https://github.com/neovim/neovim/releases/download/v${pkgver}/nvim.appimage"
        "ex"
        "view"
        "vimdiff")
postinst="${pkgname}.postinst"
prerm="${pkgname}.prerm"
sha256sums=('0c82e5702af7a11fbb916a11b4a82e98928abf8266c74b2030ea740340437bf9'
            '5d3178628afc39f0318638cad19e9ad06ada89926dfb263e93ab35cc8f60e911'
            '3cb963a264b6cf45749627408b5a62c6945e5e426b595bb5e6a388194c2c1990'
            '1d3123b9d97a4889696ab72db558041b5cca8e26ff51ae557f7842242a7d4ed1')

prepare() {
  rm -rf squashfs-root/
  chmod +x "./nvim-${pkgver}.appimage"
  "./nvim-${pkgver}.appimage" --appimage-extract
}

package() {
  echo "Copying application binary"
  install -Dm 755 squashfs-root/usr/bin/nvim -t "${pkgdir}/usr/bin/"

  echo "Copying libraries"
  install -Dm 644 squashfs-root/usr/lib/nvim/parser/c.so -t "${pkgdir}/usr/lib/nvim/parser/"

  echo "Copying application files"
  mkdir -p "${pkgdir}/usr/share/"
  cp -r squashfs-root/usr/share/applications "${pkgdir}/usr/share/applications"
  cp -r squashfs-root/usr/share/icons "${pkgdir}/usr/share/icons"
  cp -r squashfs-root/usr/share/locale "${pkgdir}/usr/share/locale"
  cp -r squashfs-root/usr/man "${pkgdir}/usr/share/man"
  cp -r squashfs-root/usr/share/nvim "${pkgdir}/usr/share/nvim"

  echo "Copying scripts for update-alternatives symbolic links"
  mkdir -p "${pkgdir}/usr/libexec/neovim"
  install -Dm 755 ex "${pkgdir}/usr/libexec/neovim/"
  install -Dm 755 view "${pkgdir}/usr/libexec/neovim/"
  install -Dm 755 vimdiff "${pkgdir}/usr/libexec/neovim/"
}

# vim:set sw=2 sts=2 et: